{
  lib,
  config,
  modulesPath,
  ...
}: {
  imports = with lib.nixosModules; [
    (modulesPath + "/installer/cd-dvd/installation-cd-minimal.nix")
    sops
  ];

  boot.extraModulePackages = with config.boot.kernelPackages; [
    rtl88xxau-aircrack
  ];

  sops = {
    gnupg.sshKeyPaths = [];
    age = {
      sshKeyPaths = [];
      keyFile = "/iso/key";
    };
    secrets = {
      home_ssid.sopsFile = lib.secrets.network-manager;
      home_psk.sopsFile = lib.secrets.network-manager;
    };
    templates.networkManager.content = ''
      home_ssid="${config.sops.placeholder.home_ssid}"
      home_psk="${config.sops.placeholder.home_psk}"
    '';
  };

  networking = {
    hostName = "dk1-iso";
    wireless.enable = false;
    networkmanager = {
      enable = true;
      ensureProfiles = {
        profiles.home = {
          connection = {
            id = "home";
            type = "wifi";
          };
          wifi = {
            ssid = "$home_ssid";
            mode = "infrastructure";
          };
          wifi-security = {
            auth-alg = "open";
            key-mgmt = "wpa-psk";
            psk = "$home_psk";
          };
        };
        environmentFiles = [config.sops.templates.networkManager.path];
      };
    };
  };
}