{
  description = "My NixOS configuration.";

  inputs = {
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-24.11";
    disko = {
      url = "github:nix-community/disko";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    impermanence.url = "github:nix-community/impermanence";
    sops-nix = {
      url = "github:Mic92/sops-nix";
      inputs.nixpkgs.follows = "nixpkgs";
    };
    nixos-anywhere = {
      url = "github:nix-community/nixos-anywhere";
      inputs = {
        nixos-stable.follows = "nixpkgs";
        disko.follows = "disko";
      };
    };
  };

  outputs = {
    self,
    nixpkgs,
    disko,
    impermanence,
    sops-nix,
    nixos-anywhere,
  }: let
    lib = nixpkgs.lib.extend self.overlays.lib;
    pkgs = nixpkgs.legacyPackages.x86_64-linux.extend self.overlays.pkgs;

    library = import ./library {inherit lib;};
  in {
    overlays = import ./overlays {
      nixos-config = self // {inherit library;};
      inherit disko impermanence sops-nix nixos-anywhere;
    };
    nixosConfigurations = import ./configurations {inherit lib;};
    nixosModules = import ./modules;

    formatter.x86_64-linux = pkgs.alejandra;
    apps.x86_64-linux = import ./applications {inherit pkgs;};
    devShells.x86_64-linux = import ./shells {inherit pkgs;};
    packages.x86_64-linux = import ./packages {inherit pkgs;};
  };
}